# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xine-lib
pkgver=1.2.10
_debver=$pkgver
_debrel=4
pkgrel=5
pkgdesc="Multimedia playback engine"
arch=('i686' 'x86_64')
url='https://www.xine-project.org'
license=('LGPL-2')
depends=('libxvmc' 'ffmpeg' 'libxinerama' 'libnsl')
makedepends=('wavpack' 'faad2' 'libmng' 'mesa' 'libmodplug'
             'vcdimager' 'jack' 'aalib' 'libdca' 'a52dec' 'libmad' 'libdvdnav'
             'libmpcdec' 'libcaca' 'glu' 'gdk-pixbuf2' 'quilt')
optdepends=('jack: for using the jack plugin'
            'vcdimager: for using the vcd plugin'
            'glu: for using the opengl plugin'
            'wavpack: for using the wavpack plugin'
            'faad2: for using the faad plugin'
            'libmng: for using the mng plugin'
            'aalib: for using the aalib plugin'
            'libmodplug: for using the modplug plugin'
            'libdca: for using the dca plugin'
            'a52dec: for using the a52 plugin'
            'libmad: for using the mp3 plugin'
            'libdvdnav: for using the dvd plugin'
            'libmpcdec: for using the musepack plugin'
            'libcaca: for using the caca plugin'
            'gdk-pixbuf2: for using the gdk-pixbuf plugin')
source=("https://downloads.sourceforge.net/project/xine/xine-lib/$pkgver/xine-lib-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/x/xine-lib-1.2/xine-lib-1.2_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('1cbe033da606d67a0a59f19968b2fe1cb46eaeb32c4b4aca7b91125b7230e15bd36d1e3e39e48e6eda56e556018f9f9bf84acb0012d3dd634306e7110fdc4c5f'
            '423ab82135999f5250b23dcb3c848cd675aa2fe0badd84e1f539ac35ffccce83605c76e140ce293a076182ff0c66653c418a3318a80934d6986c9baeddf435ca')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-Fix-ftbfs-with-gcc-10.patch || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  CFLAGS+=" -fcommon"
  ./configure \
      --prefix=/usr \
      --disable-static \
      --with-external-dvdnav \
      --with-libflac \
      --with-wavpack \
      --with-freetype \
      --disable-vdpau
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING.LIB -t "${pkgdir}/usr/share/licenses/$pkgname"
}