# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xfe
pkgver=1.45
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="X File Explorer (Xfe) is a lightweight, free and libre file manager for X"
arch=('i686' 'x86_64')
url='http://roland65.free.fr/xfe/'
license=('GPL-2')
depends=('fox' 'freetype2' 'xcb-util' 'libxft')
makedepends=('intltool' 'quilt')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/x/xfe/xfe_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/x/xfe/xfe_${_debver}-${_debrel}.debian.tar.xz"
        "libre.patch"
        "opus-support-in-xferc.patch")
sha512sums=('3d511fec3070b39c08b83c19178890dea6f7a306dee0c51a98b6ed8eafc5148973da6d803beb2053be131d389dd74eef829459fe39e212f53b983b19d5d1cb4f'
            '761e74a1ed7a4d5327f41265d02a8b507adb63d87a85022b52bd89efb3eef6a70a573803dcdbf97c42e16a5485f3cd434a5c75fc25a22b4fb2894ae567985011'
            '2dbc1374f2546aed565033f2cccef6b46df3d535db3129b9e924e6622d150ccc53fee491ab951f385d9f1b38b535798d53a3749ffb84466c42b932c91f9dab3b'
            '5adfa87130c3f4fe179858fce01110b4dc06555aeffc7c60274911c77716c686099663db4cb161375a8b3c0309584bcf47d9c4b20b04b900837eb56431ab1535')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi

  patch -p1 -i $srcdir/libre.patch
  patch -p1 -i $srcdir/opus-support-in-xferc.patch
}

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}