# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xwd package

pkgname=xenocara-xwd
_openbsdver=6.9
pkgver=1.0.7
pkgrel=3
pkgdesc="X Window System image dumping utility, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxkbfile')
makedepends=('xenocara-util-macros' 'libxt')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xwd')
conflicts=('xorg-xwd')
replaces=('xorg-xwd')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xwd-$pkgver.tar.lz{,.sig})
sha512sums=('8e0b4495c8d05e1f3f765a9ae331c3f0a6d7b495c040dded8cf80e0f90123baf35f5378aff17a0580a08d89775e6cd53746752492345cc8d5c2aab52343e5a88'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xwd"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xwd"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xwd"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}