# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xvidtune package

pkgname=xenocara-xvidtune
_openbsdver=6.9
pkgver=1.0.3
pkgrel=3
pkgdesc="Video mode tuner for Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxxf86vm' 'libxt' 'libxaw' 'libxmu' 'libx11')
makedepends=('xenocara-util-macros')
provides=('xorg-xvidtune')
conflicts=('xorg-xvidtune')
replaces=('xorg-xvidtune')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xvidtune-$pkgver.tar.lz{,.sig})
sha512sums=('6a800a0b25a947f5658d4d54ee85cbb33881f1735d23350aa2b21b59d24f886996a3e6f1f62d61b6821e5d473c1fbdd66841bf40ce7bb55af8b606a94ff936b4'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xvidtune"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xvidtune"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xvidtune"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}