# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xsetroot

pkgname=xenocara-xsetroot
_openbsdver=6.9
pkgver=1.1.2
pkgrel=3
pkgdesc="Classic X utility to set your root window background to a given pattern or color, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('X11')
depends=('libxmu' 'libx11' 'libxcursor')
makedepends=('xenocara-util-macros' 'xenocara-xbitmaps')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xsetroot')
conflicts=('xorg-xsetroot')
replaces=('xorg-xsetroot')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xsetroot-$pkgver.tar.lz{,.sig})
sha512sums=('aee83da0c7bf37f0899b375c934067210d603191fb9d75a31c1e8b983f64134b94a218d46153fc0e88b6334a0c23da80b59f86dac437454b795716501841fe19'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xsetroot"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xsetroot"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xsetroot"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}