# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xprop package

pkgname=xenocara-xprop
_openbsdver=6.9
pkgver=1.2.5
pkgrel=1
pkgdesc="Property displayer for X, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xprop')
conflicts=('xorg-xprop')
replaces=('xorg-xprop')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xprop-$pkgver.tar.lz{,.sig})
sha512sums=('58b2f96b9031774d4a991ab95a76f60b012590539b3ffe17b468f0ea1a68a76b3a33930f061d9a98ffb5da928480173a5b26686de617442cefd161991fd62667'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xprop"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xprop"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xprop"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}