# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xmag package

pkgname=xenocara-xmag
_openbsdver=6.9
pkgver=1.0.6
pkgrel=3
pkgdesc="Magnify parts of the screen, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxaw' 'libxmu' 'libxt' 'libx11')
makedepends=('xenocara-util-macros')
provides=('xorg-xmag')
conflicts=('xorg-xmag')
replaces=('xorg-xmag')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xmag-$pkgver.tar.lz{,.sig})
sha512sums=('e094414efa543c7bb7694f7163d0612d747ec86bf8570f5b9b039c33761898d4fd7ec7ab1a7756192458cc91ae88e415162796d9789ee532dac1ccc4e78cb4b3'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xmag"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xmag"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xmag"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}