# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xlsclients package

pkgname=xenocara-xlsclients
_openbsdver=6.9
pkgver=1.1.4
pkgrel=3
pkgdesc="List client applications running on a display, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxcb')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xlsclients')
conflicts=('xorg-xlsclients')
replaces=('xorg-xlsclients')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xlsclients-$pkgver.tar.lz{,.sig})
sha512sums=('e492b24a65f21159c7edfe94ed354f208f27ff222be64c7acf41276aa344afc11c551641a2b1f8e501acc240a819f6c428058adc48f17db6394cf9e7329fc69e'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xlsclients"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xlsclients"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xlsclients"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}