# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xlogo package

pkgname=xenocara-xlogo
_openbsdver=6.9
pkgver=1.0.5
pkgrel=2
pkgdesc="Draw [old] X logo, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libsm' 'libxaw' 'libxmu' 'libxt' 'libxext' 'libx11' 'libxrender' 'libxft')
makedepends=('xenocara-util-macros')
provides=('xorg-xlogo')
conflicts=('xorg-xlogo')
replaces=('xorg-xlogo')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xlogo-$pkgver.tar.lz{,.sig})
sha512sums=('5def40872de5ea0ea0dbe5e95dc25811a9fccb956d1f378bac2630786e98e67dde1ca1c5b6f0aa30523e99fa2817f85bbfc1492dc64314bb36ebe8ddfe48e5a1'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xlogo"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xlogo"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xlogo"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}