# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xload package

pkgname=xenocara-xload
_openbsdver=6.9
pkgver=1.1.3
pkgrel=3
pkgdesc="System load average display for X, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxaw' 'libxmu' 'libxt' 'libx11')
makedepends=('xenocara-util-macros' 'gettext-tiny')
provides=('xorg-xload')
conflicts=('xorg-xload')
replaces=('xorg-xload')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xload-$pkgver.tar.lz{,.sig})
sha512sums=('477262aa4da29d918b8ce6872ea0728c4232a0df5811e3688db9def726362ea5505842537868aefac3c64fd32b8efa5f73886302dec71e9c7d8a5923e618701a'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xload"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xload"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xload"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}