# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xkbutils package

pkgname=xenocara-xkbutils
_openbsdver=6.9
pkgver=1.0.4
pkgrel=3
pkgdesc="XKB utility demos, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('Expat')
depends=('libxaw' 'libxt' 'libx11')
makedepends=('xenocara-util-macros' 'xenocara-proto')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xkbutils')
conflicts=('xorg-xkbutils')
replaces=('xorg-xkbutils')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xkbutils-$pkgver.tar.lz{,.sig})
sha512sums=('9809b02a21ce08965440c9ba935e3c7cdf577245f772cb60ec8a8a893e8fce46f06a90e34144dc78f280abeeaa3034a1b87a40df474a86d44f647f1028b11638'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xkbutils"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xkbutils"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xkbutils"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}