# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xkbevd package

pkgname=xenocara-xkbevd
_openbsdver=6.9
pkgver=1.1.4
pkgrel=3
pkgdesc="XKB event daemon, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('Expat')
depends=('libxkbfile')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xkbevd')
conflicts=('xorg-xkbevd')
replaces=('xorg-xkbevd')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xkbevd-$pkgver.tar.lz{,.sig})
sha512sums=('666552f4479ebb8cd1a6d9caf77a7ea7772f8d2bcab4c1687ec8f6aa4204f6bb7128d8ef604b96dbcecff544a242504ac743b2f498b433a249a560eba968daa4'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xkbevd"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xkbevd"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xkbevd"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}