# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xkbcomp package

pkgname=xenocara-xkbcomp
_openbsdver=6.9
pkgver=1.4.4
pkgrel=2
pkgdesc="X Keyboard description compiler, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxkbfile')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xkbcomp')
conflicts=('xorg-xkbcomp')
replaces=('xorg-xkbcomp')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xkbcomp-$pkgver.tar.lz{,.sig})
sha512sums=('bd25ae266cda7c33dec8db163c5126543376f47e4a176ecf5f428587742036207342a3adf80415c671828b2dcd94a54b46a1424a013ad5fc7d649aa61fe4c1f9'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xkbcomp"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xkbcomp"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xkbcomp"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}