# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xinput package

pkgname=xenocara-xinput
_openbsdver=6.9
pkgver=1.6.3
pkgrel=2
pkgdesc="Small commandline tool to configure devices, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('Expat')
depends=('libx11' 'libxi>=1.7.10' 'xenocara-xrandr' 'libxinerama')
makedepends=('xenocara-util-macros' 'xenocara-proto' 'libxfixes')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xinput')
conflicts=('xorg-xinput')
replaces=('xorg-xinput')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xinput-$pkgver.tar.lz{,.sig})
sha512sums=('b46eab24828ba9856817b107ce34a00618cb199e8ac3ddcd9d60e2894ad5658f3fa19334984e50e6395e93a9988ef3a4d6aedb5a9f8534248a352cff54a99695'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xinput"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xinput"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xinput"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}