# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xfontsel package

pkgname=xenocara-xfontsel
_openbsdver=6.9
pkgver=1.0.6
pkgrel=3
pkgdesc="Point and click selection of X11 font names, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
makedepends=('xenocara-util-macros')
depends=('libxaw' 'libxmu' 'libxt' 'libx11')
provides=('xorg-xfontsel')
conflicts=('xorg-xfontsel')
replaces=('xorg-xfontsel')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xfontsel-$pkgver.tar.lz{,.sig})
sha512sums=('72487bb1bd3d94fdb3ac3a9db5e750dc14d0188d02e9210ba801e61570e129c7234af8c9c4b6fa28f10d05fba22dddad753b08583a94d3efed120ee46092ebe8'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xfontsel"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xfontsel"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xfontsel"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}