# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xfd package

pkgname=xenocara-xfd
_openbsdver=6.9
pkgver=1.1.3
pkgrel=2
pkgdesc="Displays all the characters in a font using either the X11 core protocol or libXft2, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxaw' 'fontconfig' 'libxft' 'libxrender' 'libxmu' 'libxkbfile')
makedepends=('xenocara-util-macros' 'gettext-tiny')
provides=('xorg-xfd')
conflicts=('xorg-xfd')
replaces=('xorg-xfd')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xfd-$pkgver.tar.lz{,.sig})
sha512sums=('b3dedb84a98189ef6e9e6a0ca88239866ce0a652e727b74e91238a6f9c293f3174cf0669aefb4e3a15e53d488682ddf0cf865d19b6b977f959f7454447b4628c'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xfd"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xfd"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xfd"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}