# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xeyes package

pkgname=xenocara-xeyes
_openbsdver=6.9
pkgver=1.1.2
pkgrel=3
pkgdesc="Follow the mouse/SHAPE extension X demo, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('X11')
depends=('libx11' 'libxt' 'libxext' 'libxmu' 'libxrender')
makedepends=('xenocara-util-macros')
provides=('xorg-xeyes')
conflicts=('xorg-xeyes')
replaces=('xorg-xeyes')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xeyes-$pkgver.tar.lz{,.sig})
sha512sums=('7ba8046d3f6c8f0cea69317a5ad7589deffeb03301e739d58882ec7c82f8fb21366f855d2d3669a51035987a890c2d254ec0f78ebbc1eedd52309e4bc0a65cba'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xeyes"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xeyes"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xeyes"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}