# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xev package

pkgname=xenocara-xev
_openbsdver=6.9
pkgver=1.2.4
pkgrel=1
pkgdesc="Print contents of X events, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11' 'libxrandr')
makedepends=('xenocara-util-macros' 'xenocara-proto')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xev')
conflicts=('xorg-xev')
replaces=('xorg-xev')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xev-$pkgver.tar.lz{,.sig})
sha512sums=('318229c59977a7cda2deb2d94d0fcda20cfeb5d644bae955c401492c694f99381fedf7b370c5a460564191021760500e003e4a85a70dac87a2eda1b982c0bfe5'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xev"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xev"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xev"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}