# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xdriinfo package

pkgname=xenocara-xdriinfo
_openbsdver=6.9
pkgver=1.0.6
pkgrel=3
pkgdesc="Query configuration information of DRI drivers, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('Expat')
depends=('libx11' 'libgl')
makedepends=('xenocara-util-macros' 'xenocara-proto')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xdriinfo')
conflicts=('xorg-xdriinfo')
replaces=('xorg-xdriinfo')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xdriinfo-$pkgver.tar.lz{,.sig})
sha512sums=('e1b15943784f0b469cd8a704ba1fdf4d68e2dd489a064b63a72c8c44374d0e4396e83bf6e24bd905f3425b3962497d006fa4f26c9fb4288e7a92bdcbc1a2f7b8'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xdriinfo"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xdriinfo"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xdriinfo"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}