# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xconsole package

pkgname=xenocara-xconsole
_openbsdver=6.9
pkgver=1.0.7
pkgrel=3
pkgdesc="Monitor system console messages with X, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('X11')
depends=('libxaw' 'libxmu' 'libxt' 'libx11')
makedepends=('xenocara-util-macros')
provides=('xorg-xconsole')
conflicts=('xorg-xconsole')
replaces=('xorg-xconsole')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xconsole-$pkgver.tar.lz{,.sig})
sha512sums=('d7142de44da9729e48b88249cfa2be499e0950df315777bd6a61ea5929722fb7283ac22ea517d4b4efca8948c479682b4611a6699c4f181dbc1fd4136ce5b54f'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xconsole"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xconsole"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xconsole"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}