# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xcompmgr package

pkgname=xenocara-xcompmgr
_openbsdver=6.9
pkgver=1.1.8
pkgrel=2
pkgdesc="Composite Window-effects manager for Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('Expat')
depends=('libxcomposite' 'libxdamage' 'libxrender' 'libxext')
makedepends=('xenocara-util-macros')
provides=('xcompmgr')
conflicts=('xcompmgr')
replaces=('xcompmgr')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xcompmgr-$pkgver.tar.lz{,.sig})
sha512sums=('6f91dbe8a2b832baed180bd72096cac53753bdedb2052d7a8fc87cb0eb87adab65a7fe3fab29c4c69747a849e17b09de2ae38ed8910f8ca0dd6e73f405ec59fe'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xcompmgr"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xcompmgr"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xcompmgr"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}