# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-x11perf package

pkgname=xenocara-x11perf
_openbsdver=6.9
pkgver=1.6.1
pkgrel=2
pkgdesc="Simple X server performance benchmarker, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('Expat')
depends=('libx11' 'libxmu' 'libxrender' 'libxft' 'libxext')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-x11perf')
conflicts=('xorg-x11perf')
replaces=('xorg-x11perf')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/x11perf-$pkgver.tar.lz{,.sig})
sha512sums=('b4edd9d70bc1112325fd2821a9755360c3c65abc5cebfdd65abb6bc918aa37c2806a6af73cd08d108dded4680543c5f45cda53e645c39768f320e4f7506fe02e'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/x11perf"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/x11perf"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/x11perf"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}