# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-twm package

pkgname=xenocara-twm
_openbsdver=6.9
pkgver=1.0.10
pkgrel=3
pkgdesc="Tab Window Manager for the X Window System, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
backup=(usr/share/X11/twm/system.twmrc)
license=('X11')
depends=('libxmu' 'libbsd')
makedepends=('xenocara-util-macros')
provides=('xorg-twm')
conflicts=('xorg-twm')
replaces=('xorg-twm')
options=('!emptydirs')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/twm-$pkgver.tar.lz{,.sig}
        add-libbsd-support.patch)
sha512sums=('1a91e2ca5e33a1209d6c038844fe8e6a65a2a9893783a97c82ceb10659ea14cbbc0658c95b7654b3c3e41930a61c734b486428c713adfbe2de815fabfa136e25'
            'SKIP'
            'b1afa6b118395f92003d96d3ac9609c432c984f34dfde3910be5df98e5d75de417e9d20ae41352d2fe33e05f23a80d8e450af36b59d9dd629b1953d26ad69c46')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/twm"
  patch -p1 -i "$srcdir/add-libbsd-support.patch"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/twm"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/twm"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}