# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-setxkbmap package

pkgname=xenocara-setxkbmap
_openbsdver=6.9
pkgver=1.3.2
pkgrel=2
pkgdesc='Set the keyboard using the X Keyboard Extension, provided by Xenocara'
url="https://www.xenocara.org"
license=('Expat')
arch=('i686' 'x86_64')
depends=('libxkbfile')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-setxkbmap')
conflicts=('xorg-setxkbmap')
replaces=('xorg-setxkbmap')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/setxkbmap-$pkgver.tar.lz{,.sig})
sha512sums=('b16dfb2c99f069b5cc01294af5afd4bc873dcaa23311104f2b4411b83405a86b75559161131f31a4d187c3e6e22b6ca2c5d700a58ad1a4e020584d98f7ef0a2d'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/setxkbmap"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/setxkbmap"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/setxkbmap"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}