# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-luit package

pkgname=xenocara-luit
_openbsdver=6.9
pkgver=1.1.1
pkgrel=3
pkgdesc="Filter that can be run between an arbitrary application and a UTF-8 terminal emulator, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('Expat')
depends=('libfontenc')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-luit')
conflicts=('xorg-luit')
replaces=('xorg-luit')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/luit-$pkgver.tar.lz{,.sig}
        git-fixes.patch)
sha512sums=('b637daa4e087f235d141ee38ca172962b9f79c47805a69456dbcd746209f43de2a4273aac18469ae56304c43a50b5baed551fe19571f5e69aa24334981014531'
            'SKIP'
            'bde23389de4ef0cf3c9df962cc03f556b24463765d8794d9d53400252542a542fe28a4218ec978d0edd648a783d11eee66f0ad0d8af79a68c111d3dc672d0801')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/luit"
  patch -p1 -i "$srcdir/git-fixes.patch"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/luit"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/luit"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}