# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-iceauth package

pkgname=xenocara-iceauth
_openbsdver=6.9
pkgver=1.0.8
pkgrel=3
pkgdesc="ICE authority file utility, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libice')
makedepends=('xenocara-util-macros' 'xenocara-proto')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-iceauth')
conflicts=('xorg-iceauth')
replaces=('xorg-iceauth')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/iceauth-$pkgver.tar.lz{,.sig})
sha512sums=('4e0aa38c1183110039fe4d659406cac31ea077eca2880e56079e8715a46eb293a1be3980fa4e3416bc1cac37e2ad42ad753e441f4f2721667fe76cee8229e0b9'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/iceauth"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/iceauth"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/iceauth"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}