# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-docs package

pkgname=xenocara-docs
_openbsdver=6.9
pkgver=1.7.1
pkgrel=3
pkgdesc="Xenocara documentations"
arch=(any)
url="https://www.xenocara.org"
license=('Expat')
depends=('man-db')
makedepends=('xenocara-util-macros')
groups=('xenocara' 'xorg')
provides=('xorg-docs')
conflicts=('xorg-docs')
replaces=('xorg-docs')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/doc/xorg-docs-$pkgver.tar.lz{,.sig}
        COPYING)
sha512sums=('3dd29d440695b2bc4167a6db5420cf8be586b9482a959f6607082fc48544c2d8482a378b72fbb97f5f64c8d1af8633537b7d018e512519125973629ccb731815'
            'SKIP'
            '9edfd3f8922f67c89aea5fe3cbd3ceefa714147e48747e17320c9f6b4e234a8c60bfb203039de197e83aa7a81b013916ad14d254fcb4d1570a529f8fd7d97732')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/doc/xorg-docs"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/doc/xorg-docs"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/doc/xorg-docs"
  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir/COPYING" "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}