# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-appres package

pkgname=xenocara-appres
_openbsdver=6.9
pkgver=1.0.5
pkgrel=3
pkgdesc="List X application resource database, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('X11')
depends=('libxt')
makedepends=('xenocara-util-macros')
provides=('xorg-appres')
conflicts=('xorg-appres' 'xorg-res-utils')
replaces=('xorg-appres')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/appres-$pkgver.tar.lz{,.sig})
sha512sums=('2acbc464a5bec4685e1a17646e8489102a0ec33ff6c4e5606e5953f85edfcf051efad527a930c2fd9eb4c00a4757bbdbbe3009d89df12f7691efdcb19e181e05'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/appres"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/appres"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/appres"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}