# Maintainer: Jesus E. <heckyel@riseup.net>
# Committer (Arch): Judd Vinet <jvinet@zeroflux.org>

pkgname=xautolock
pkgver=2.2
_debver=$pkgver
_debrel=8
pkgrel=2
pkgdesc="An automatic X screen-locker"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('libxss')
makedepends=('xorg-imake' 'quilt')
source=("$pkgname-$pkgver.tar.gz::https://deb.debian.org/debian/pool/main/x/xautolock/xautolock_$pkgver.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/x/xautolock/xautolock_$_debver-$_debrel.debian.tar.xz")
sha512sums=('5f9dcc25cda706610e77a74235c4b421ca3a833d154b1a269057f0774579e1c6ec36fe0e5be5fadd6942ce8c1640a760f891397586b162e6024b524635153d04'
            '7cc8e6e71ac6607cf446de586d25d876e1a97acce65e4261d93be002f8bdb92a25f9a07a14ed0220aec501c89e130b44b8b6065ab5972dd3089bf5128e67f828')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  xmkmf
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  make DESTDIR="$pkgdir" install.man
  install -Dm644 License -t $pkgdir/usr/share/licenses/$pkgname
}