# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xapian-core
pkgver=1.4.18
pkgrel=1
epoch=1
pkgdesc='Free search engine library.'
arch=('i686' 'x86_64')
url="https://www.xapian.org/"
license=('GPL-2')
makedepends=('util-linux')
depends=('bash' 'gcc-libs' 'glibc' 'zlib' 'libutil-linux')
options=('libtool')
source=("https://oligarchy.co.uk/xapian/${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.asc})
sha512sums=('ba6240054c0d2f92b9f1059aa934cdf35388ee7c7e05f4ef6f9856bdaed8ad821095a348ed9a892afdf18c3c0ad20e163028ad0ed3a9934bd69b861e814678ef'
            'SKIP')
validpgpkeys=('08E2400FF7FE8FEDE3ACB52818147B073BAD2B07') # Olly Betts <olly@debian.org>

prepare() {
  cd "${pkgname}-${pkgver}"
  autoreconf -vfi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -vDm 644 {AUTHORS,ChangeLog,HACKING,NEWS,README} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
}