# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=wxgtk
pkgname=('wxgtk2' 'wxgtk3' 'wxgtk-common')
pkgver=3.0.5.1
_debver=$pkgver
_debrel=2
pkgrel=2
arch=('i686' 'x86_64')
url='https://wxwidgets.org'
license=('wxWindows-Library-3.1')
makedepends=('gst-plugins-base' 'glu' 'gtk' 'gtk2' 'quilt')
options=('!emptydirs')
source=(https://github.com/wxWidgets/wxWidgets/releases/download/v$pkgver/wxWidgets-${pkgver}.tar.bz2
        https://deb.debian.org/debian/pool/main/w/wxwidgets3.0/wxwidgets3.0_${_debver}+dfsg-${_debrel}.debian.tar.xz)
sha512sums=('0a789fc5e71d414e43f75b5c16076fe8b1bcd7671be0770e4269dcef66d830c1bc74e183f49db270b928862f13472666c283fe2aa98b9006681722e06100725d'
            '574c28fe8b864ed3652313bc22f6eb15d4264203dab4cdabe11a34508a8a61fcac1c65af5835518e603c6306d910d753614ae0f9a6d0303eb59b35451927d01e')

prepare() {
  cd wxWidgets-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cd ..
  cp -r wxWidgets-$pkgver wxWidgets-$pkgver-gtk3
}

build() {
  cd wxWidgets-$pkgver
  ./configure --prefix=/usr --libdir=/usr/lib --with-gtk=2 --with-opengl --enable-unicode \
    --enable-graphics_ctx --enable-mediactrl --with-regex=builtin \
    --with-libpng=sys --with-libxpm=sys --with-libjpeg=sys --with-libtiff=sys \
    --disable-precomp-headers --with-libnotify=no
  make
  make -C locale allmo

  cd ../wxWidgets-$pkgver-gtk3
  ./configure --prefix=/usr --libdir=/usr/lib --with-gtk=3 --with-opengl --enable-unicode \
    --enable-graphics_ctx --enable-mediactrl --with-regex=builtin \
    --with-libpng=sys --with-libxpm=sys --with-libjpeg=sys --with-libtiff=sys \
    --disable-precomp-headers --with-libnotify=no
  make
}

package_wxgtk-common() {
  pkgdesc='Common libraries and headers for wxgtk2 and wxgtk3'
  depends=('zlib' 'gcc-libs' 'expat')

  cd wxWidgets-$pkgver
  make DESTDIR="$pkgdir" install
  rm -r "$pkgdir"/usr/{bin/wx-config,lib/{wx,libwx_gtk*}}

  install -D -m644 docs/licence.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}

package_wxgtk2() {
  pkgdesc='GTK+2 implementation of wxWidgets API for GUI'
  depends=('gtk2' 'libgl' 'gst-plugins-base-libs' 'libsm' 'libxxf86vm' 'wxgtk-common')

  cd wxWidgets-$pkgver
  make DESTDIR="$pkgdir" install
  rm -r "$pkgdir"/usr/{include,share,lib/libwx_base*,bin/wxrc*}

  install -D -m644 docs/licence.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}

package_wxgtk3() {
  pkgdesc='GTK+3 implementation of wxWidgets API for GUI'
  depends=('gtk' 'gst-plugins-base-libs' 'libsm' 'libxxf86vm' 'wxgtk-common')

  cd wxWidgets-$pkgver-gtk3
  make DESTDIR="$pkgdir" install
  rm -r "$pkgdir"/usr/{include,share,lib/libwx_base*,bin/wxrc*}
  mv "$pkgdir"/usr/bin/wx-config{,-gtk3}

  install -Dm644 docs/licence.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}