# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=wvdial
pkgver=1.61
_debver=$pkgver
_debrel=6
pkgrel=2
pkgdesc="A dialer program to connect to the Internet"
arch=('i686' 'x86_64')
license=('LGPL-2')
depends=('wvstreams' 'ppp' 'gcc-libs')
makedepends=('lockdev' 'quilt')
options=('!makeflags' '!buildflags')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/w/wvdial/wvdial_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/w/wvdial/wvdial_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('13bd74a1c3c95236ff5f408041f9f02ee926e585a55d251a7fe4068ea87a23ed1eede0467e7c67fbb10a942de1d84c7a38185c92582479a8bf0978ab8c5a92aa'
            'c8f1528f074592846bc43f1323c929d1e942f36874e13a86819de801375ad15e8977bd54e5161d9ad0c7f2b8c859c05123dbc498bd83ac47123533615283cb13')

prepare() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  ./configure
  make LOCKDEV="-llockdev"
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  make prefix="${pkgdir}"/usr PPPDIR="${pkgdir}"/etc/ppp/peers install
  install -Dm644 COPYING.LIB -t "${pkgdir}"/usr/share/licenses/${pkgname}
}