# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=worker
pkgver=4.11.0
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A file manager for the X Window System"
arch=('i686' 'x86_64')
license=('GPL-2')
url='http://www.boomerangsworld.de/worker'
depends=('libx11' 'libxt' 'file' 'xenocara-proto')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.bz2::https://deb.debian.org/debian/pool/main/w/worker/worker_${pkgver}.orig.tar.bz2"
        "https://deb.debian.org/debian/pool/main/w/worker/worker_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('17675e90d15ef323e81efedf96b53ce0aa1fe22f58f298498a9740657e297114c3f7ca8b4f24e63269a7a87c78e09b881c9cef4a6fe42f46f7457bf4187f5834'
            '604f6c48f7bf6f476bace45ee6c2538f17cae3693eef32b4b6e923275b4ccb398e0796b12d746288c760e403b95c443c709b4aa9c21cfafde7dabd1e949a63ae')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  CPPFLAGS="-O0 -std=gnu++14" LDFLAGS=-pthread ./configure \
    --prefix=/usr \
    --enable-xft \
    --disable-cxx-check
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}