# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=vcdimager
pkgver=2.0.1
_debver=$pkgver
_debrel=6
pkgrel=2
pkgdesc="A full-featured mastering suite for authoring disassembling and analyzing Video CD's and Super Video CD's"
url='https://www.gnu.org/software/vcdimager/'
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('libcdio' 'libxml2' 'popt')
makedepends=('quilt')
source=("https://ftp.gnu.org/gnu/vcdimager/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/v/vcdimager/vcdimager_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('55a9d235149a35fe26576703c623a2c9a3f7deedd2e42e01271fdf1e1fdf14c51ee040ee3b5d15fe1b5860fbd4cbeb437362b1a1f40187c8d4d691b6b89a2230'
            'b09e8fd9b5b5cad99b4b5bf7556785c847042a188455568995c71bc553f4a28b6de500da24e09880acddb10f924784b39179a05deb58837c34479fc9675a2290')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
}


build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}