# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=upx
pkgver=3.96
_debver=3.96
_debrel=2
pkgrel=1
pkgdesc='Extendable, high-performance executable packer for several executable formats'
arch=(i686 x86_64)
url='https://github.com/upx/upx'
license=(custom:GPL-2+UPX-Linking-Exception)
depends=(ucl)
makedepends=(perl quilt)
source=("https://github.com/$pkgname/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver-src.tar.xz"
        "https://deb.debian.org/debian/pool/main/u/upx-ucl/upx-ucl_$_debver-$_debrel.debian.tar.xz")
sha512sums=('2d4d1be21d274d9bfdee9b9815396f5e5ff0bcdfb781b7be5fafa4d1e224028e412ec5f5ba607c482671aae27ccf9069abb2db0fb58f78f3a102a51897df2b11'
            '84a491a89b9dd43d73aea804a2c57e3f3ceaa288a54a8972b8046afc6bcec0a38ebf1db2bebc7edfd500a3322621c3d69973df15df23bcd51bd03a22d25d7477')

prepare() {
  cd $pkgname-$pkgver-src
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  make -C $pkgname-$pkgver-src \
    CHECK_WHITESPACE=/bin/true \
    UPX_LZMA_VERSION=0x465 \
    UPX_LZMADIR="$srcdir" \
    all
}

package() {
  cd $pkgname-$pkgver-src
  install -Dm755 src/upx.out "$pkgdir/usr/bin/upx"
  install -Dm644 doc/upx.1 "$pkgdir/usr/share/man/man1/upx.1"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: ts=2 sw=2 et: