# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=unixodbc
pkgver=2.3.11
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="ODBC is a free specification for providing application developers with a predictable API with which to access Data Sources"
arch=('i686' 'x86_64')
license=('GPL-2' 'LGPL-2.1')
url="http://www.unixodbc.org/"
backup=('etc/odbc.ini' 'etc/odbcinst.ini')
depends=('readline' 'libtool')
makedepends=('quilt')
source=(http://www.unixodbc.org/unixODBC-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/u/unixodbc/unixodbc_$_debver-$_debrel.debian.tar.xz)
sha512sums=('dddc32f90a7962e6988e1130a8093c6fb8b9ff532cad270d572250324aecbc739f45f9d8021d217313910bab25b08e69009b4f87456575535e93be1f46f5f13d'
            '0c960f1c752ecae19ce11eb0f01589c1ebd7ed957f1f6ce1aa16f5c9a8d20635bcede2e371af68c0f54c20ec7b5c000cd787dda3bd52f6f44d524ad532abb780')

prepare() {
    cd unixODBC-${pkgver}
    if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
      # Debian patches
      export QUILT_PATCHES=debian/patches
      export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
      export QUILT_DIFF_ARGS='--no-timestamps'

      mv "$srcdir"/debian .

      quilt push -av
    fi
    autoreconf -vfi
}

build() {
    cd unixODBC-${pkgver}
    ./configure --prefix=/usr --sysconfdir=/etc
    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
    make
}

check() {
    cd unixODBC-${pkgver}
    make -k check
}

package() {
    cd unixODBC-${pkgver}
    make DESTDIR=${pkgdir} install
    touch "$pkgdir"/etc/{odbc,odbcinst}.ini
    install -Dm644 exe/COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING.GPL
    install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING.LGPL
}