# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ucl
pkgver=1.03
_debver=1.03+repack
_debrel=6
pkgrel=8
pkgdesc="Portable lossless data compression library written in ANSI C"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
url="https://www.oberhumer.com/opensource/ucl/"
source=("https://www.oberhumer.com/opensource/$pkgname/download/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/u/ucl/ucl_$_debver-$_debrel.debian.tar.xz")
sha512sums=('7dd1824d01b4bb41ee03bbceddc634a9f7f910d235e5cca163d783680d6743f0f3cc309bbbcc1e094d897d549d3805a555f9093b4d77805443d896dd1862aa34'
            '9ee2cab5d74db52381ba44ec4d2adf3b0ead245cc902d9a3dda16c56b0c58adbf998a20d7bd7c94128b5a082cc3b8c5cd288c47dcb24577a128bcb7a229f68c9')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  CFLAGS+=" -std=gnu90 -fPIC"
  ./configure --prefix=/usr --enable-shared --disable-static
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}