# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=treesheets
pkgver=1.0.2
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Free and libre data organizer that covers spreadsheets, mind mappers and small databases"
arch=('i686' 'x86_64')
url='https://strlen.com/treesheets/'
license=('zlib')
depends=('glibc' 'wxgtk3')
makedepends=('cmake' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/t/treesheets/treesheets_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/t/treesheets/treesheets_${_debver}-${_debrel}.debian.tar.xz"
        "$pkgname.desktop")
sha512sums=('889ac62c0a884643925161229ea2c7f94e26ac8e3d78161c26e319b5baaa9db668d72017fc0430911c1b3f831dbc06b7e7efe3aca60f99b1ac2df343c906ca8d'
            'ea8bbaf9d6809ad6031b2c30cb7371f5276f14855fe98a700947c4a419e222355fd249ad83edac5ad0b586ee3fe31016efdd60c9759da8ba3dff5433e316dadf'
            'f9d7f2a092c2cfb3b942ac6becdafefcb78d30cfe9d304ea540bb1a56a4ade14e813ea071454cdd886bfd54200ec9254b97afc056fc7f7832edd49d1de7c52d8')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  export WX_CONFIG=wx-config-gtk3
  cmake \
    -S $pkgname-$pkgver \
    -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DPACKAGE_VERSION="$pkgver-hyperbola"
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install
  install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
  install -Dm644 "$srcdir/$pkgname-$pkgver/$pkgname/treesheets-32x32.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -Dm644 "$srcdir/$pkgname-$pkgver/debian/copyright" -t "$pkgdir/usr/share/licenses/$pkgname"
}