# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tree
pkgver=2.1.0
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A directory listing program displaying a depth indented list of files"
arch=('i686' 'x86_64')
url='http://mama.indstate.edu/users/ice/tree/'
license=('GPL-2')
depends=('glibc')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/t/tree/tree_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/t/tree/tree_$_debver-$_debrel.debian.tar.xz")
sha512sums=('17947b17e5fd4d06aea17be0cb107340a0537fb60cd5ee76524ef6eca37a775dbe9a4a7060d54f90a64ac1310131bf76b878fdb4384ab1a5fcb3180787c35a87'
            '6c32658106c849144d68fecd88ab08b2c46f20f9961fb7c83d48df5d96bd2edb59bf84aa8e5ca130fd2d6bd4290373328eec11f48fd4c7e508261495acc463a0')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make PREFIX="${pkgdir}/usr" MANDIR="${pkgdir}/usr/share/man" install
  install -Dm644 LICENSE -t $pkgdir/usr/share/licenses/$pkgname/
}