# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tre
pkgver=0.8.0
_debver=0.8.0
_debrel=6
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc='POSIX compliant regexp matching library. Includes agrep for approximate grepping.'
url='https://laurikari.net/tre'
depends=('glibc')
makedepends=('quilt')
license=('Simplified-BSD')
source=("https://laurikari.net/tre/$pkgname-$pkgver.tar.bz2"
        "https://deb.debian.org/debian/pool/main/t/tre/tre_$_debver-$_debrel.debian.tar.xz")
sha512sums=('db7465993e0d25eee8e52f974427b8a040234cf0f017769eb94ee88bc6261821336aad7f762bfa82db7e2212d8449bc221592586f061c528a59a550773cbc263'
            'dc66e38a074fe4d65a8440c1c5b23015b5a4254ad30240e76ea5d6d5bc1f46e552c5a99672879996cf6c3694ada133c92c05022b9570aec76f1512f0bfc16b89')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/99-autoreconf || true

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr --enable-static
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -d "$pkgdir/usr/share/doc/$pkgname"

  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"

  cd doc
  for f in default.css tre-api.html tre-syntax.html; do
    install -Dm644 "$f" "$pkgdir/usr/share/doc/$pkgname/$f"
  done
}