# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=transcode
pkgver=1.1.7
_debver=$pkgver
_debrel=9
pkgrel=2
pkgdesc="A video/DVD ripper and encoder for the terminal/console"
arch=('i686' 'x86_64')
license=('GPL-2')
depends=('gawk' 'lzo' 'libdvdread' 'ffmpeg' 'mjpegtools' 'sdl' 'libmpeg2' 'libxaw' 'a52dec' 'libsndio' 'libquicktime')
makedepends=('nasm' 'x264' 'quilt')
source=("https://repo.hyperbola.info:50000/sources/${pkgname}/${pkgname}-${pkgver}.tar.bz2"{,.sig}
        "https://repo.hyperbola.info:50000/sources/${pkgname}/${pkgname}_${_debver}-${_debrel}.debian.tar.xz"{,.sig}
        "transcode-ffmpeg3.patch"
        "transcode-ffmpeg4.patch"
        "transcode-swresample.patch"
        "transcode-sndio.patch")
sha512sums=('d6f9674f3f5c3346194120585741ca660eb9ee133085cfce9460a14eaa0cf16fdf291761bd1db78e1c784e4d69a9481c7470cf8357dc7638ee3017620500f45f'
            'SKIP'
            '4f52627e01e4ae172006fa55f8f2aab6b1ae457d0b12ad966fe942ee220bfebb32864bc32d727db6e490a8fdf0e6e2dcad7016cfb9eedc3c5b3391fb18ab67b6'
            'SKIP'
            '0491de7cb189f4e634ad6fbb45051fd883bbf5787a89dbe93c633b2b48e96c031da0686a6fd9f61d621133a0a93410d8d73a96ad18f519ad7788aceb8a35fb2d'
            'b13a60193444d28ae8103eee677c0b8a1f52d0517e73de166319f221ab50f05eb045427aa6e963a759722476e8f8304f714c8666d3ffbf37825bcaf1348f803f'
            'af04f4c52508144dcbad3ea5fb8d9f00a94248bce6a0b76fb20bb9f9999dcfb7f3ad696a3fe4d2d17cbe014fbfa86d7ddd3feedefcf912bd4e952b5848f32581'
            'f5d55516b6ca2d2c0cffd2c87c2df377b5dae94385894f5b103894821d618ee9cd6374cb2be779014675b956a672c24908cb1278db7b854d1581014fe0942f74')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/01_filter_pv.c.diff || true
    rm -v debian/patches/03_libav-api-fixes.diff || true
    rm -v debian/patches/04_ffmpeg_options.patch || true
    rm -v debian/patches/05-libav9-gentoo.patch || true
    rm -v debian/patches/06_libav9-jmm.patch || true
    rm -v debian/patches/07_libav9-preset.patch || true
    rm -v debian/patches/08_libav9-opt.patch || true
    rm -v debian/patches/09_libav9-arch.patch || true
    rm -v debian/patches/11_libav10.patch || true
    rm -v debian/patches/12_underlinkage.patch || true

    quilt push -av
  fi

  patch -p1 -i ${srcdir}/transcode-ffmpeg3.patch
  patch -p1 -i ${srcdir}/transcode-ffmpeg4.patch
  patch -p1 -i ${srcdir}/transcode-sndio.patch
  sed -e 's|freetype/ftglyph.h|freetype2/freetype/ftglyph.h|' -i filter/subtitler/load_font.c
  patch -p1 -i ${srcdir}/transcode-swresample.patch

  autoreconf -vi
}


build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --disable-sse \
    --disable-sse2 \
    --disable-altivec \
    --disable-imagemagick \
    --enable-mmx \
    --enable-lame \
    --enable-ogg \
    --enable-vorbis \
    --enable-theora \
    --enable-libdv \
    --enable-libxml2 \
    --enable-v4l \
    --enable-libjpeg \
    --enable-lzo \
    --enable-mjpegtools \
    --enable-sdl \
    --enable-freetype2 \
    --enable-a52 \
    --enable-libpostproc \
    --enable-xvid \
    --enable-x264 \
    --enable-alsa \
    --enable-sndio \
    --enable-libmpeg2 \
    --enable-libmpeg2convert \
    --enable-libquicktime

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}