# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=toppler
pkgver=1.1.6
pkgrel=2
pkgdesc="A classic, free and libre jump & run game in which you climb the rotating towers"
arch=('i686' 'x86_64')
url="https://sourceforge.net/projects/toppler/"
license=('GPL-3')
depends=('gcc-libs' 'sdl_mixer' 'zlib')
makedepends=('intltool' 'gettext-tiny')
groups=('games')
source=("https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
        "$pkgname.desktop")
sha512sums=('e0f6b7b72e38ba3402ba3608116fb51bf36cad129fb5591db62489829f4ed1ec49a4a3b7b1db4aaa34cd1561ee5228d91577f550aad2d55520ccefdff9bda9e9'
            'faaca963de797282c148c41c1d57657ddaf0686b80328bf144ebe58208ee118c822e36d5dc5c7a0af6f4691e54f04e55fb25709e890d8efe04f1c4b9c83b9a81')

build() {
  cd "$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datadir=/usr/share/games \
    --localstatedir=/usr/share/games
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  # correcting wrong folder-locations
  mv "${pkgdir}/usr/share/games/"{doc,locale,pixmaps} "${pkgdir}/usr/share"
  rm -rf "${pkgdir}/usr/share/games/applications"

  # install desktop-file
  install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"

  # install license
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}