# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tmux
pkgver=3.2a
_debver=$pkgver
_debrel=4
pkgrel=1
pkgdesc="A terminal multiplexer"
url='https://github.com/tmux/tmux/wiki'
arch=('i686' 'x86_64')
license=('ISC')
depends=('ncurses' 'libevent' 'libutempter')
makedepends=('quilt' 'automake-1.15')
source=("https://github.com/tmux/tmux/releases/download/${pkgver}/tmux-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/t/tmux/tmux_${_debver}-${_debrel}~bpo11+1.debian.tar.xz")
sha512sums=('6e52c7f5d03b2c8b8c4c8caac092a166956ba97334b426f2823d74dc5849a1d31a80145924f641f69dd2c244809e9350d9bd7070897fa2e3e1f9f086f9b2f365'
            '7ab1807f438d21e1ba64d93b864645c16c48e627333958ee4a1f1261c7930de75369bba5c2e7034928e108d08703a6d8fb526ca123442eaf16fb0c0a13033c8f')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --enable-utempter
  make
}

package() {
  cd $pkgname-$pkgver

  make install DESTDIR="$pkgdir"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}