# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tinyxml2
pkgver=8.0.0
_debver=8.0.0+dfsg
_debrel=2
pkgrel=1
pkgdesc='Simple XML parser made for easy integration'
arch=('i686' 'x86_64')
url='http://www.grinninglizard.com/tinyxml2'
license=('zlib')
makedepends=('cmake' 'ninja' 'setconf' 'quilt')
source=($pkgname-$pkgver.tar.gz::https://github.com/leethomason/$pkgname/archive/$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/t/tinyxml2/tinyxml2_$_debver-$_debrel.debian.tar.xz)
sha512sums=('bcbb065c2af34ea681ec556377fd22e720b6f5d4caa73f432b1e34e08603a96f2233763f0ec5ae86b9ee71ddbe3062f58d3794cd3a162ce6903435530de0bba6'
            'f9bf8010bff37c51b06a73b49e3700c91bbf2a0cc8bcabe53729920d271d3de979a8cc5e335612c30a556a4ae07f92ed2719eed61410add9b41f904808019264')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cd ..
  grep License -A20 "$srcdir/$pkgname-$pkgver/readme.md" > LICENSE
}

build() {
  mkdir -p build
  cd build
  cmake "../$pkgname-$pkgver" \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=Release \
    -G Ninja
  ninja
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}