# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tinyproxy
pkgver=1.10.0
_debver=$pkgver
_debrel=5
pkgrel=2
pkgdesc="A light-weight, free and libre HTTP proxy daemon for POSIX operating systems."
arch=('i686' 'x86_64')
url='https://tinyproxy.github.io/'
license=('GPL-2')
depends=('glibc' 'gawk')
makedepends=('asciidoc' 'quilt')
backup=('etc/tinyproxy/tinyproxy.conf')
source=("https://github.com/${pkgname}/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.asc}
        "https://security.debian.org/debian-security/pool/updates/main/t/tinyproxy/tinyproxy_${_debver}-${_debrel}+deb11u1.debian.tar.xz"
        "tinyproxy.initd"
        "tinyproxy.run")
sha512sums=('8d82598c5f9c89bc672f4632139ac52696d5c7788963de51688a8aeb576c69004f8338fe1e1897bf704a21dfd25ab1effb092003b6afaa9a88c2b5d0608310f5'
            'SKIP'
            '2d46819ad0a6da6827ae47a25897dee38dd0c61478f760c767f11eab6d18db1f3b42d443d98d891479ffead2890c80d7ba2eb5cc681de14f31dec25872afb3c3'
            'cd440ed686e8128ed46441ca29da8376c4d28e9e34ae9b85c18eb2f1681d60c0c04b79401a7368f917eeab6768965d6c867d0ac6578a7858557c11b356446c02'
            '40c1ccf23f5cc5328a92045ac60137cfdcfae207e3eb0dbc4d2ed84c489aa803e4628adbe7a8c67c41ac6153c05eaa272a3b993cd3ffa6b6cfb79d3af1d24cee')
validpgpkeys=('38871449E065D635620A621EC94F4938184F9034') # Michael Adam <obnox@samba.org>

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-transparent
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  # services install
  install -Dm755 "${srcdir}"/${pkgname}.initd "${pkgdir}"/etc/init.d/$pkgname
  install -Dm755 "${srcdir}"/${pkgname}.run "${pkgdir}"/etc/sv/$pkgname/run

  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}