# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tevent
pkgver=0.10.2
_debver=0.10.2
_debrel=1
pkgrel=1
epoch=1
pkgdesc='Event system based on the talloc memory management library'
url='https://tevent.samba.org/'
arch=('i686' 'x86_64')
source=(https://samba.org/ftp/tevent/${pkgname}-${pkgver}.tar{.gz,.asc}
        https://deb.debian.org/debian/pool/main/t/tevent/tevent_${_debver}-${_debrel}.debian.tar.xz
        LICENSE)
license=('GPL-3' 'LGPL-3' 'Modified-BSD')
depends=('talloc')
makedepends=('python' 'quilt')
optdepends=('python: for python bindings')
validpgpkeys=('9147A339719518EE9011BCB54793916113084025') # Samba Library Distribution Key <samba-bugs@samba.org>
sha512sums=('1da8f28898f35daab515892b880d1de601062cc3e2b2570cd62e6913df17b0195a05acb7b484c628cddc0eb8b0cde893105ede3feb32bc5764e7d25684f332ba'
            'SKIP'
            '18a0a9d8075e09f086675ab0225821c95acf743589dac5d607520169999382fadf7bbf03265001f4ba23d6b4047d63207bb4cf6b29f53a78e2d8f5a9dc12f955'
            '4b7df5a04fe468ed547e934e67945bb3814a786f1c930ca82dd9c389b2614246d06856f2828816e1b9f14a83a988775c170e6adf3f1b3dd1a484575d84909147')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --bundled-libraries=NONE \
    --builtin-libraries=replace
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 "${srcdir}/LICENSE" -t "${pkgdir}/usr/share/licenses/$pkgname"
}