# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=terminus-font
pkgver=4.48
_debver=4.48
_debrel=3
pkgrel=2
pkgdesc='Monospace bitmap font (for X11 and console)'
url='http://terminus-font.sourceforge.net/'
arch=('any')
license=('OFL-1.1')
makedepends=('xenocara-bdftopcf' 'python' 'quilt')
source=(https://downloads.sourceforge.net/project/terminus-font/terminus-font-$pkgver/terminus-font-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/x/xfonts-terminus/xfonts-terminus_$_debver-$_debrel.debian.tar.xz)
sha512sums=('5f45f7d0e7396f02158f4751aaafb3f0a3fb68dbe3e5501f86a5138c6d52f5106053e38c368d560e5979e29250074dbde5165702b8905a564d029663a2219af4'
            '7082b18f7d5c75e8ea3a16341c8a49f667b6af7ed3524d7d08b6fcb5b7ba9afe778807b85c1f457981afbd9d5da5b8e75b9dae1daef886ecdc1af9bdd186e9a6')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --x11dir=/usr/share/fonts/misc \
    --psfdir=/usr/share/kbd/consolefonts
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -Dm644 "$srcdir/terminus-font-$pkgver/75-yes-terminus.conf" \
    "$pkgdir/etc/fonts/conf.avail/75-yes-terminus.conf"
  install -Dm644 "$srcdir/$pkgname-$pkgver/OFL.TXT" -t \
    "$pkgdir/usr/share/licenses/$pkgname"
  install -d "$pkgdir/etc/fonts/conf.d"

  cd "$pkgdir/etc/fonts/conf.d"
  ln -s ../conf.avail/75-yes-terminus.conf .
}