# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tecnoballz
pkgver=0.93.1
_debver=$pkgver
_debrel=10
pkgrel=1
pkgdesc="Free and libre breaking block game"
arch=('i686' 'x86_64')
url='http://linux.tlk.fr/games/TecnoballZ/'
license=('GPL-3')
depends=('sdl_image' 'sdl_mixer' 'tinyxml')
makedepends=('quilt')
groups=('games')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/t/tecnoballz/tecnoballz_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/t/tecnoballz/tecnoballz_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('a7e30d408f907b9b5bbbf20002088d3cb84b7ee22b92b8ebbe14ad056036ce291ecd61531402c876047f69f2068ce844c5351dbf9e29a240b321a6d365c3c1ea'
            'c37e3200201b1c80193c6688130938bade0fee655ffbaa67c37213bb4c7a500107c92cb29d5df5a9a5276627d2806d7e17945dc7c30f9fdffb70eba002159f7f')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --datadir=/usr/share/games
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -Dm644 man/$pkgname.6 -t "$pkgdir/usr/share/man/man6"
  install -Dm644 debian/$pkgname.desktop -t "$pkgdir/usr/share/applications"
  install -Dm644 debian/$pkgname.xpm -t "$pkgdir/usr/share/pixmaps"
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}