# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=tcp-wrappers
pkgname=('libwrap' 'tcp-wrappers')
pkgver=7.6.31
pkgrel=1
pkgdesc='Monitors and Controls incoming TCP connections'
arch=('i686' 'x86_64')
url=ftp://ftp.porcupine.org/pub/security/index.html
license=('Expat')
depends=('glibc' 'libnsl')
source=(ftp://ftp.porcupine.org/pub/security/tcp_wrappers_${pkgver%.*}.tar.gz
        https://deb.debian.org/debian/pool/main/t/tcp-wrappers/tcp-wrappers_${pkgver%.*}.q-${pkgver##*.}.debian.tar.xz
        tcp-wrappers-redhat-bug11881.patch
        hosts.allow
        hosts.deny)
sha512sums=('2d9d003791f8d00912a36ae00579e2b8dd7ad8a7bf8eae259659bcaf5365b150540ff6c93c91765872c76041579b7a02b6e3c64528fb7f8235680399ba1d9dac'
            'de2bd7b081fca0f182def93795014332baf7b5edf339eaf81dff82772aea1dc866ccddccd5273e7dc49cf760953e164a66f1e5945cb54f2b8dab090c11712c33'
            '5d6d9fea060a6801bca98c65dfaa2e94e77830416126950b8941a38758b9e177825c31f3878753ce6170b97a12326c3efd09647c5d5a233ebd715d171f296098'
            'c73beac92c6b860d2ff4ca7d339297080824552413d10944d665ac4ec48b18f607b0516972ff82158521739c8e5f8c3ba52ddb6012ea048236a80f117f70ca36'
            'ab5d61dde6fa845d15f830ec5300e571ce0eaf6a96c938b9a52811f83de984b5ab0fb583e4ff8df9fdf01c976270f5c1212034a08654926b11d63eda80289976')

prepare() {
  cd tcp_wrappers_${pkgver%.*}

  for patch in $(cat ../debian/patches/series); do
    patch -Np1 -i ../debian/patches/${patch}
  done
  patch -Np1 -i ../tcp-wrappers-redhat-bug11881.patch
}

build() {
  cd tcp_wrappers_${pkgver%.*}

  make \
    COPTS="$CFLAGS" \
    LDOPTS="$LDFLAGS" \
    STYLE='-DPROCESS_OPTIONS' \
    linux
}

package_libwrap() {
  provides=(tcp_wrappers-libs)
  conflicts=(tcp_wrappers-libs)

  cd tcp_wrappers_${pkgver%.*}

  install -Dm 644 tcpd.h -t "${pkgdir}"/usr/include/
  install -Dm 644 shared/libwrap.so.0.${pkgver%.*} -t "${pkgdir}"/usr/lib/
  ln -s libwrap.so.0.${pkgver%.*} "${pkgdir}"/usr/lib/libwrap.so.0
  ln -s libwrap.so.0 "${pkgdir}"/usr/lib/libwrap.so

  install -Dm 644 DISCLAIMER -t "${pkgdir}"/usr/share/licenses/$pkgname/
}

package_tcp-wrappers() {
  depends=(libwrap)
  provides=(tcp_wrappers)
  conflicts=(tcp_wrappers)
  backup=(
    etc/hosts.allow
    etc/hosts.deny
  )

  cd tcp_wrappers_${pkgver%.*}

  install -Dm 755 safe_finger tcpd tcpdchk tcpdmatch try-from -t "${pkgdir}"/usr/bin/
  install -Dm 644 *.3 -t "${pkgdir}"/usr/share/man/man3/
  install -Dm 644 *.5 -t "${pkgdir}"/usr/share/man/man5/
  install -Dm 644 *.8 -t "${pkgdir}"/usr/share/man/man8/
  install -Dm 644 ../hosts.{allow,deny} -t "${pkgdir}"/etc/
  install -Dm 644 README -t "${pkgdir}"/usr/share/doc/tcp-wrappers/

  install -Dm 644 DISCLAIMER -t "${pkgdir}"/usr/share/licenses/$pkgname/
}