# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=tcc
pkgver=0.9.27+git20200814.62c30a4a
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Tiny C Compiler"
arch=('i686' 'x86_64')
url='https://bellard.org/tcc/'
license=('LGPL-2.1')
makedepends=('texi2html' 'quilt')
options=('staticlibs')
source=("https://deb.debian.org/debian/pool/main/t/tcc/tcc_${pkgver}.orig.tar.bz2"
        "https://deb.debian.org/debian/pool/main/t/tcc/tcc_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('daf19c20c53edd35c96d7d12b59345b8e2ec464b86744c0b3a1713bacf54ad2a803febfe03f53ba6c12e40c3ba5e6d0eebaebef1892fe394376ee324299943c0'
            'af5cd3747e42b04fefa17367fa040e0925e4c98087a778b5aaa754fe13811ed429971d5b158bd4bb36d381075c58c5074fc1f4824c67b8218fa03ccb65de8187')
noextract=("tcc_${pkgver}.orig.tar.bz2")

prepare() {
  mkdir -p ${pkgname}-${pkgver}
  tar -xf "tcc_${pkgver}.orig.tar.bz2" \
      -C  "${pkgname}-${pkgver}/"
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make -j1 test
}

package() {
  make -C ${pkgname}-${pkgver} DESTDIR="$pkgdir" docdir="$pkgdir"/usr/share/doc/tcc install
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/COPYING" -t "${pkgdir}/usr/share/licenses/$pkgname"
}